Atlas - CMakeLists.txt
Home / ext / SDL / src / hidapi / linux
Lines: 1 | Size: 1130 bytes
[Download] [Show on GitHub] [Search similar files] [Raw] [Raw (proxy)] 
[FILE BEGIN]
1cmake_minimum_required(VERSION 3.6.3...3.25 FATAL_ERROR)
2
3add_library(hidapi_hidraw
4    ${HIDAPI_PUBLIC_HEADERS}
5    hid.c
6)
7target_link_libraries(hidapi_hidraw PUBLIC hidapi_include)
8
9find_package(Threads REQUIRED)
10
11include(FindPkgConfig)
12pkg_check_modules(libudev REQUIRED IMPORTED_TARGET libudev)
13
14target_link_libraries(hidapi_hidraw PRIVATE PkgConfig::libudev Threads::Threads)
15
16set_target_properties(hidapi_hidraw
17    PROPERTIES
18        EXPORT_NAME "hidraw"
19        OUTPUT_NAME "hidapi-hidraw"
20        VERSION ${PROJECT_VERSION}
21        SOVERSION ${PROJECT_VERSION_MAJOR}
22        PUBLIC_HEADER "${HIDAPI_PUBLIC_HEADERS}"
23)
24
25# compatibility with find_package()
26add_library(hidapi::hidraw ALIAS hidapi_hidraw)
27# compatibility with raw library link
28add_library(hidapi-hidraw ALIAS hidapi_hidraw)
29
30if(HIDAPI_INSTALL_TARGETS)
31    install(TARGETS hidapi_hidraw EXPORT hidapi
32        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
33        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
34        PUBLIC_HEADER DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/hidapi"
35    )
36endif()
37
38hidapi_configure_pc("${PROJECT_ROOT}/pc/hidapi-hidraw.pc.in")
39
[FILE END]
(C) 2025 0x4248
(C) 2025 4248 Media and 4248 Systems, All part of 0x4248
See LICENCE files for more information. Not all files are by 0x4248 always check Licencing.