Atlas - CMakeLists.txt
Home / ext / SDL / src / hidapi / mac
Lines: 1 | Size: 1420 bytes
[Download] [Show on GitHub] [Search similar files] [Raw] [Raw (proxy)] 
[FILE BEGIN]
1cmake_minimum_required(VERSION 3.4.3...3.25 FATAL_ERROR)
2
3list(APPEND HIDAPI_PUBLIC_HEADERS "hidapi_darwin.h")
4
5add_library(hidapi_darwin
6    ${HIDAPI_PUBLIC_HEADERS}
7    hid.c
8)
9
10find_package(Threads REQUIRED)
11
12target_link_libraries(hidapi_darwin
13    PUBLIC hidapi_include
14    PRIVATE Threads::Threads
15    PRIVATE "-framework IOKit" "-framework CoreFoundation"
16)
17
18set_target_properties(hidapi_darwin
19    PROPERTIES
20        EXPORT_NAME "darwin"
21        OUTPUT_NAME "hidapi"
22        VERSION ${PROJECT_VERSION}
23        SOVERSION ${PROJECT_VERSION_MAJOR}
24        MACHO_COMPATIBILITY_VERSION ${PROJECT_VERSION_MAJOR}
25        FRAMEWORK_VERSION ${PROJECT_VERSION_MAJOR}
26        PUBLIC_HEADER "${HIDAPI_PUBLIC_HEADERS}"
27)
28
29# compatibility with find_package()
30add_library(hidapi::darwin ALIAS hidapi_darwin)
31# compatibility with raw library link
32add_library(hidapi ALIAS hidapi_darwin)
33
34set(PUBLIC_HEADER_DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
35if(NOT CMAKE_FRAMEWORK)
36    set(PUBLIC_HEADER_DESTINATION "${PUBLIC_HEADER_DESTINATION}/hidapi")
37endif()
38
39if(HIDAPI_INSTALL_TARGETS)
40    install(TARGETS hidapi_darwin EXPORT hidapi
41        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
42        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
43        FRAMEWORK DESTINATION "${CMAKE_INSTALL_LIBDIR}"
44        PUBLIC_HEADER DESTINATION "${PUBLIC_HEADER_DESTINATION}"
45    )
46endif()
47
48hidapi_configure_pc("${PROJECT_ROOT}/pc/hidapi.pc.in")
49
[FILE END]
(C) 2025 0x4248
(C) 2025 4248 Media and 4248 Systems, All part of 0x4248
See LICENCE files for more information. Not all files are by 0x4248 always check Licencing.